on adding folder items to this_folder after receiving these_items
	set project to (this_folder as text) & "project.impproj"
	set done_folder to "Done"
	tell application "Finder"
		if not (exists folder done_folder of this_folder) then
			make new folder at this_folder with properties {name:done_folder}
		end if
		set the destination_folder to folder done_folder of this_folder as alias
		set the destination_directory to POSIX path of the destination_folder
	end tell
	repeat with i from 1 to number of items in these_items
		set this_item to item i of these_items
		set the item_info to info for this_item
		if this_item is not the destination_folder and the name extension of the item_info is "pdf" then
			set the item_path to the POSIX path of this_item
			set the destination_path to the destination_directory & (name of the item_info)
			
			tell application "Imposition Wizard"
				activate
				open project
				tell first document
					set source to item_path
					impose in destination_path
					close saving no
				end tell
			end tell
		end if
	end repeat
end adding folder items to